home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
DS-CD ROM 2 1993 August
/
DS CD-ROM 2.Ausgabe (August 1993).iso
/
programm
/
ds0257
/
install.bat
< prev
next >
Wrap
DOS Batch File
|
1992-02-25
|
10KB
|
348 lines
@ECHO OFF
REM ----------------
REM INSTALL V1.20 - Batch-Datei zum Installieren von Lib4A86
REM (c) Bernd Schemmer 1992
REM ----------------
REM :: Für 4DOS 3.02 auf BTM umschalten!
IF %@eval[2+2] == 4 LOADBTM ON
CLS
REM :: Ausgabe des Logos
ECHO. ┌─────────────────────────────────────────────────────────────────┐
ECHO. │ INSTALL.BAT - Batchdatei zum Entpacken der Archive von Lib4A86 │
ECHO. └─────────────────────────────────────────────────────────────────┘
ECHO.
REM :: Testen, ob die Datei von der richtigen Diskette gestartet wurde
IF EXIST START.DOC GOTO DiskOK
ECHO. * INSTALL fataler Fehler: Falsche Start-Diskette benutzt!
ECHO.
ECHO. * INSTALL.BAT kann nur von der Original-Diskette der Shareware-
ECHO. * Version oder der ERSTEN Diskette der Vollversion (bzw. einer
ECHO. * Kopie einer dieser beiden Disketten) gestartet werden!
ECHO. *
ECHO. * Beende INSTALL
ECHO.
GOTO ENDE
:DiskOK
ECHO. Initialisiere die Variablen. Bitte warten, das dauert etwas ...
ECHO. (evtl. Fehlermeldungen wie 'Kein Platz mehr im Umgebungsbereich'
ECHO. können ignoriert werden, da sie von INSTALL behandelt werden!)
ECHO.
REM :: Voreinstellungen für die Parameter
SET Z_LW=C:
SET Q_LW=A:
SET MKDIRS=J
REM :: Environment-Speicher belegen
SET EXT=xxxxxxxxxxxxx
SET RETADR=%EXT%
SET RETADR1=%EXT%
SET FILE=%EXT%
REM :: Auswerten der Parameter
IF %1. == ?. GOTO HELP
IF %1. == /?. GOTO HELP
IF %1. == -?. GOTO HELP
IF NOT %1. == . SET Z_LW=%1
IF NOT %2. == . SET Q_LW=%2
IF NOT %3. == . SET MKDIRS=%3
IF NOT %4. == . GOTO SwitchError1
REM :: Testen, ob die Environment-Variablen erstellt werden konnten
SET TEST=****TEST****
IF NOT %TEST%. == ****TEST****. GOTO EnvError
SET TEST=
REM :: Parameter überprüfen
IF %Z_LW%. == C:. GOTO LwOK1
IF %Z_LW%. == c:. GOTO LwOK1
IF %Z_LW%. == D:. GOTO LwOK1
IF %Z_LW%. == d:. GOTO LwOK1
GOTO ZWLError
:LwOK1
IF %Q_LW%. == A:. GOTO LwOK2
IF %Q_LW%. == a:. GOTO LwOK2
IF %Q_LW%. == B:. GOTO LwOK2
IF %Q_LW%. == b:. GOTO LwOK2
GOTO QWLError
:LwOK2
IF %MKDIRS%. == J. GOTO SwitchOK
IF NOT %MKDIRS%. == N. GOTO SwitchError
:SwitchOK
CLS
REM :: Ausgabe des Logos
ECHO. ┌─────────────────────────────────────────────────────────────────┐
ECHO. │ INSTALL.BAT - Batchdatei zum Entpacken der Archive von Lib4A86 │
ECHO. └─────────────────────────────────────────────────────────────────┘
ECHO.
GOTO S%MKDIRS%
:SJ
ECHO. INSTALL erstellt im (akt.) Verzeichnis (von)
CD %Z_LW%
ECHO. folgende Verzeichnisstruktur:
ECHO. Inhalt
ECHO. »akt. Dir« allgemeine .DOC-Dateien und SHOW.COM
ECHO. ────────────┐
ECHO. ├──\LIB *.LIB, *.BIB und *.MAB
ECHO. │
ECHO. ├──\DEMO .DEM- u. .MAB-Dateien zu den Dateien aus ..\LIB
ECHO. │
ECHO. ├──\DOC .DOC-Dateien zu den Dateien aus ..\LIB
ECHO. │
ECHO. ├──\UTIL Utilities aus Lib4A86 und die Dokumentation dazu
ECHO. -- nur in der Vollversion: --
ECHO. └──\INC kommentierte Quelltexte der Dateien aus ..\LIB
GOTO S00
:SN
ECHO.
ECHO. Die Directorys LIB, DEMO, DOC und UTIL (und evtl. INC) existieren
ECHO. bereits im Directory
CD %Z_LW%
:S00
ECHO. ┌────┐ ┌────┐
ECHO. Installiere Lib4A86 vom Laufwerk │ %Q_LW% │ aus ins Laufwerk │ %Z_LW% │.
ECHO. └────┘ └────┘
ECHO.
ECHO. Soll ich fortfahren (CTRL-C für Abbruch, INSTALL ? für Hilfe)?
PAUSE >NUL
CLS
ECHO. Installiere Lib4A86 im akt. Directory des Laufwerkes %Z_LW% ...
ECHO.
SET EXT=.EXE
copy %Q_LW%show.com %Z_LW%
REM :: Entpacken der allgemeinen Dokumentation ...
SET FILE=README
SET RETADR=S2
:S2
IF NOT EXIST %Q_LW%%FILE%%EXT% GOTO AskUser1
ECHO.
ECHO. * Entpacke das Archiv %FILE%%EXT% ...
%Z_LW%
%Q_LW%%FILE%%EXT%
IF ERRORLEVEL == 1 GOTO ERROR
ECHO. * %FILE%%EXT% entpackt.
REM :: Entpacken der Libary-Files ...
SET FILE=LIB
SET RETADR1=M1
GOTO MKFiles%MKDIRS%
:M1
REM :: Entpacken der .DOC-Files ...
SET FILE=DOC
SET RETADR1=M2
GOTO MKFiles%MKDIRS%
:M2
REM :: Entpacken der Demo-Files ...
SET FILE=DEMO
SET RETADR1=M3
GOTO MKFiles%MKDIRS%
:M3
ECHO. * Kopiere die .MAC- und .MAP-Dateien ins Directory DEMO ...
%Z_LW%
copy LIB\*.MA? DEMO\*.* >NUL
REM :: Entpacken der Utilities ...
SET FILE=UTIL
SET RETADR1=M4
GOTO MKFiles%MKDIRS%
:M4
SET FILE=INC
IF EXIST %Q_LW%%FILE%%EXT% GOTO M5_1
ECHO.
ECHO. * Falls Sie die Vollversion von Lib4A86 auf 360-K-Disketten
ECHO. * besitzen, jetzt bitte die 2. Diskette einlegen und eine
ECHO. * Taste drücken.
ECHO.
ECHO. * In allen anderen Fällen einfach nur eine Taste drücken ...
PAUSE >NUL
ECHO.
REM :: Testen, ob es sich um eine Vollversion handelt ...
IF NOT EXIST %Q_LW%%FILE%%EXT% GOTO M5
:M5_1
SET RETADR1=M5
GOTO MKFiles%MKDIRS%
:M5
REM :: Hilfsvariablen Löschen
SET RETADR=
SET RETADR1=
SET FILE=
SET EXT=
ECHO.
ECHO. Lib4A86 ist nun installiert.
ECHO.
ECHO. Beachten Sie bitte, daß Sie vor der Nutzung von Lib4A86 erst die
ECHO. Environment-Variablen A86 und A86LIB (und evtl. Lib4A86) definieren
ECHO. müssen (siehe 'Lib4A86.PRT').
ECHO.
REM :: Ins Ziellaufwerk umschalten
%Z_LW%
REM :: Hilfsvariablen löschen
SET Z_LW=
SET Q_LW=
SET MKDIRS=
ECHO. Möchten Sie sich nun die allgemeine Dokumentation zu Lib4A86 ansehen?
ECHO.
ECHO. Bitte eine Taste drücken ... (CTRL-C für Abbruch)
PAUSE >NUL
show Lib4A86.prt history.doc
GOTO ENDE
REM ----------------
REM Unterroutine zum Entpacken der Archive
REM Eingabe: %FILE% = Name des Archivs
REM %EXT% = Extension des Archivs
REM %RETADR1% = Marke, an der die Programmausführung fort-
REM geführt werden soll
REM
:MKFilesJ
ECHO.
ECHO. * Erstelle das Directory %FILE% ..
MD %Z_LW%%FILE% >NUL
:MKFilesN
COPY %Q_LW%START.DOC %Z_LW%%FILE%\*.* >NUL
IF NOT EXIST %Z_LW%%FILE%\START.DOC GOTO DirectoryError
DEL %Z_LW%%FILE%\START.DOC >NUL
%Z_LW%
CD %Z_LW%%FILE% >NUL
SET RETADR=S4
:S4
IF NOT EXIST %Q_LW%%FILE%%EXT% GOTO AskUser1
ECHO.
ECHO. * Entpacke das Archiv %FILE%%EXT% ...
%Q_LW%%FILE%%EXT%
IF ERRORLEVEL == 1 GOTO ERROR
CD .. >NUL
ECHO.
ECHO. * %FILE%%EXT% entpackt.
GOTO %RETADR1%
REM ----------------
:DirectoryError
ECHO.
ECHO. * Fehler: Directory %FILE% existiert nicht bzw. konnte nicht
ECHO. * erstellt werden!
ECHO.
GOTO EENDE
REM ----------------
:ERROR
CD .. >NUL
ECHO.
ECHO. * Fehler beim Entpacken des Archivs %Q_LW%%FILE%%EXT% aufgetreten!
ECHO.
GOTO EENDE
REM ----------------
:EnvError
ECHO.
ECHO. * Fehler: Nicht genügend Platz im Environment
ECHO.
ECHO. Zur Ausführung dieser Datei müssen Sie den Platz im Environment
ECHO. erhöhen. Falls Ihr Kommando-Interpreter der COMMAND.COM ist
ECHO. müssen Sie hierzu in der Datei CONFIG.SYS die Zeile
ECHO.
ECHO. SHELL=d:\COMMAND.COM /e:nnnnn /p
ECHO.
ECHO. einfügen oder editieren. Hierbei ist 'd:' das Verzeichnis, in dem
ECHO. der COMMAND.COM steht und 'nnnnn' die Größe des Environments in Byte.
ECHO. (siehe auch DOS-Handbuch)
ECHO.
ECHO. Falls Sie diese Änderung des Systems nicht wünschen, können Sie INSTALL
ECHO. auch folgendermaßen aufrufen:
ECHO.
ECHO. COMMAND /e:2048 /C install.bat {parameter für install}
ECHO.
IF %COMSPEC%. == . GOTO ENDE
ECHO. Drücken Sie eine Taste zur Ausführung dieser Datei über den Befehl
ECHO.
ECHO. %COMSPEC% /e:2048 /C install.bat %1 %2 %3
ECHO.
ECHO. oder CTRL-C für Abbruch ...
PAUSE >NUL
%COMSPEC% /e:2048 /C install.bat %1 %2 %3
GOTO Ende
:QWLError
ECHO.
ECHO. * Fehler: Als zweiter Parameter (%2%) ist nur A: oder B: erlaubt!
GOTO EEnde
REM ----------------
:ZWLError
ECHO.
ECHO. * Fehler: Als erster Parameter (%1%) ist nur D: oder C: erlaubt!
GOTO EEnde
REM ----------------
:SwitchError
ECHO.
ECHO. * Fehler: Als dritter Parameter (%3) ist nur J oder N erlaubt!
GOTO EEnde
REM ----------------
:SwitchError1
ECHO.
ECHO. * Fehler: Zuviele Parameter angegeben!
GOTO EEnde
REM ----------------
REM Unterroutine zur Ausgabe einer Fehlermeldung und zum Lesen einer Taste
REM Eingabe: %FILE% = Name des Archivs
REM %EXT% = Extension des Archivs
REM %RETADR% = Marke, an der die Programmausführung fort-
REM geführt werden soll.
:AskUser1
ECHO. * INSTALL - FEHLER *
ECHO.
ECHO. Kann die Datei %FILE%%EXT% im Laufwerk %Q_LW% nicht finden.
ECHO. Bitte die richtige Diskette ins Laufwerk %Q_LW% einlegen
ECHO. und eine Taste drücken (CTRL-C für Abbruch) ...
PAUSE >NUL
ECHO.
GOTO %RETADR%
REM ----------------
:HELP
CLS
ECHO. ┌─────────────────────────────────────────────────────────────────┐
ECHO. │ INSTALL.BAT - Batchdatei zum Entpacken der Archive von Lib4A86 │
ECHO. └─────────────────────────────────────────────────────────────────┘
ECHO.
ECHO. Aufruf: INSTALL {ziellaufwerk} {quelllaufwerk} {J ODER N}
ECHO.
ECHO. mit: Ziellaufwerk = Laufwerk, auf dem die Dateien entpackt
ECHO. werden sollen. Mögliche Angaben: C: oder D:
IF NOT "%Z_LW%" == "" ECHO. (Voreinstellung: %Z_LW%)
ECHO. Quelllaufwerk = Laufwerk, in dem die Archive von Lib4A86
ECHO. sind. Mögliche Angaben: A: oder B:
IF NOT "%Q_LW%" == "" ECHO. (Voreinstellung: %Q_LW%)
ECHO. N = Directorys nicht erstellen, da sie schon
ECHO. vorhanden sind.
ECHO. ODER J = Directorys erstellen, da sie noch nicht
ECHO. vorhanden sind.
IF NOT "MKDIRS" == "" ECHO. (Voreinstellung: %MKDIRS%)
ECHO.
ECHO. Beispiel: INSTALL D: B: J
ECHO. - Installieren von Lib4A86 im akt. Directory des Laufwerks
ECHO. D:, wobei die Diskette mit den Archiven im Laufwerk B:
ECHO. liegt. Die Directorys werden explizit erstellt.
ECHO.
GOTO ENDE
:EENDE
ECHO. (INSTALL ? für Hilfe)
ECHO.
ECHO. Beende die Ausführung von INSTALL.
ECHO.
:ENDE
REM :: Löschen der verwendeten Environment-Variablen ...
SET RETADR=
SET RETADR1=
SET FILE=
SET EXT=
SET Z_LW=
SET Q_LW=
SET MKDIRS=